Para crear un link en un Flash (hecho en ActionScript 3) debemos seguir estos pasos:

Primero debemos crear la librería. Vamos a Flash y creamos un nuevo documento AS.

Luego pegamos el siguiente código:

package com.utils { 
   import flash.net.URLRequest; 
   import flash.net.navigateToURL; 
 
   public class PopUp { 
 
      private var _url:String = "http://www.mononelo.es"; 
      private var _width:Number= 400; 
      private var _height:Number= 300; 
      private var _title:String = "title"; 
      private var _resize:String = "yes"; 
      private var _window:String = "_blank"; 
 
      public function PopUp() { 
      } 
 
      public function openWindow(newUrl:String = null):void{ 
         if(newUrl) 
            this.url = newUrl; 
         var _urlRequest:URLRequest=new URLRequest(); 
         _urlRequest.url= "javascript:window.open('"+url+"','"+title+"','width="+width+",height="+height+", resizable="+resize+"');newWindow.focus(); void(0);"; 
         navigateToURL(_urlRequest,_window); 
      } 
 
 
      public function set url(val:String):void { 
         _url = val; 
      } 
 
      public function get url():String { 
         return _url; 
      } 
 
      public function set width(val:Number):void { 
         _width = val; 
      } 
 
      public function get width():Number { 
         return _width; 
      } 
 
      public function set height(val:Number):void { 
         _height = val; 
      } 
 
      public function get height():Number { 
         return _height; 
      } 
 
      public function set title(val:String):void { 
         _title = val; 
      } 
 
      public function get title():String { 
         return _title; 
      } 
 
      public function set resize(val:String):void  { 
         _resize = val; 
      } 
 
      public function get resize():String { 
         return _resize; 
      } 
 
      public function set window(val:String):void { 
         _window = val; 
      } 
 
      public function get window():String { 
         return _window; 
      } 
   } 
}

Este archivo lo ponemos, con el nombre PopUp.as, en una carpeta determinada (si no la tenemos la creamos manualmente): /raíz_del_flash/com/utils/PopUp.as

Entonces para llamarlo utilizamos el siguiente código:

import com.utils.PopUp; 
 
var t:PopUp = new PopUp(); 
 
 
btn1.addEventListener(MouseEvent.CLICK, popUpNormal); 
btn2.addEventListener(MouseEvent.CLICK, popUpEditado); 
 
function popUpNormal(e:MouseEvent):void { 
   var ir:String; 
   ir="http://www.mononelo.es"; 
   t.openWindow(ir); 
} 
 
function popUpEditado(e:MouseEvent):void { 
   t.url="http://www.google.com"; 
   t.title="Estamos en Google"; 
   t.width=640; 
   t.height=480; 
   t.resize="yes"; 
   t.window="_self"; 
   t.openWindow(); 
}